Si está en SQL Server 2016+
Puedes usar el nuevo STRING_SPLIT
función, sobre la que he escrito aquí, y Brent Ozar ha escrito aquí.
SELECT s.[message-id], f.value
FROM dbo.SourceData AS s
CROSS APPLY STRING_SPLIT(s.[recipient-address], ';') as f;
Si todavía tiene una versión anterior a SQL Server 2016
Crear una función de división. Este es solo uno de los muchos ejemplos que existen:
CREATE FUNCTION dbo.SplitStrings
(
@List NVARCHAR(MAX),
@Delimiter NVARCHAR(255)
)
RETURNS TABLE
AS
RETURN (SELECT Number = ROW_NUMBER() OVER (ORDER BY Number),
Item FROM (SELECT Number, Item = LTRIM(RTRIM(SUBSTRING(@List, Number,
CHARINDEX(@Delimiter, @List + @Delimiter, Number) - Number)))
FROM (SELECT ROW_NUMBER() OVER (ORDER BY s1.[object_id])
FROM sys.all_objects AS s1 CROSS APPLY sys.all_objects) AS n(Number)
WHERE Number <= CONVERT(INT, LEN(@List))
AND SUBSTRING(@Delimiter + @List, Number, 1) = @Delimiter
) AS y);
GO
He discutido algunos otros aquí, aquí, y un mejor enfoque que dividir en primer lugar aquí.
Ahora puede extrapolar simplemente por:
SELECT s.[message-id], f.Item
FROM dbo.SourceData AS s
CROSS APPLY dbo.SplitStrings(s.[recipient-address], ';') as f;
También sugiero no poner guiones en los nombres de las columnas. Significa que siempre tienes que ponerlos entre [square brackets]
.