Como mínimo, debe consultar ALL_TAB_COLUMNS, no ALL_TABLES
DECLARE
match_count integer;
v_search_string varchar2(4000) := <<string you want to search for>>;
BEGIN
FOR t IN (SELECT owner, table_name, column_name FROM all_tab_columns) LOOP
EXECUTE IMMEDIATE
'SELECT COUNT(*) FROM '||t.owner || '.' || t.table_name||
' WHERE '||t.column_name||' = :1'
INTO match_count
USING v_search_string;
IF match_count > 0 THEN
dbms_output.put_line( t.owner || '.' || t.table_name ||' '||t.column_name||' '||match_count );
END IF;
END LOOP;
END;
/
Sin embargo, si está buscando una cadena, es casi seguro que querrá limitarse a buscar columnas que puedan almacenar una cadena. No tendría sentido, por ejemplo, buscar una cadena en una columna FECHA. Y a menos que tenga un gran conocimiento a priori sobre lo que contiene una columna BLOB y la capacidad de analizar el formato binario de la columna BLOB, no tendría sentido buscar una cadena en una columna BLOB. Dado eso, sospecho que quieres algo más como
DECLARE
match_count integer;
v_search_string varchar2(4000) := <<string you want to search for>>;
BEGIN
FOR t IN (SELECT owner,
table_name,
column_name
FROM all_tab_columns
WHERE data_type in ('CHAR', 'VARCHAR2', 'NCHAR', 'NVARCHAR2',
'CLOB', 'NCLOB') )
LOOP
BEGIN
EXECUTE IMMEDIATE
'SELECT COUNT(*) FROM '||t.owner || '.' || t.table_name||
' WHERE '||t.column_name||' = :1'
INTO match_count
USING v_search_string;
IF match_count > 0 THEN
dbms_output.put_line( t.owner || '.' || t.table_name ||' '||t.column_name||' '||match_count );
END IF;
EXCEPTION
WHEN others THEN
dbms_output.put_line( 'Error encountered trying to read ' ||
t.column_name || ' from ' ||
t.owner || '.' || t.table_name );
END;
END LOOP;
END;
/
Por supuesto, esto va a ser increíblemente lento:escanearía por completo cada tabla una vez para cada columna de cadena en la tabla. Con tablas moderadamente grandes y un número moderado de columnas de cadenas, es probable que lleve bastante tiempo.
