Consolide varios activadores de Oracle. ¿Algún impacto en el rendimiento?

Ahora he evaluado esta situación y llegué a la conclusión de que hay una pérdida de rendimiento significativa probablemente debido a los cambios de contexto de PL/SQL, al agregar 1 disparador. La pérdida es por factor 8 en mi punto de referencia. Sin embargo, agregar un segundo activador "compatible" ya no tiene un impacto significativo. Por "compatible", me refiero a que ambos disparadores siempre se activan en el mismo evento en cualquier orden.

Así que llego a la conclusión de que lo más probable es que solo haya 1 SQL -> PL/SQL cambio de contexto para todos los activadores

Aquí está el punto de referencia:

Crear una tabla

-- A typical table with primary key, creation/modification user/date, and 
-- other data columns
CREATE TABLE test(
  id number(38)    not null, -- pk
  uc varchar2(400) not null, -- creation user
  dc date          not null, -- creation date
  um varchar2(400),          -- modification user
  dm date,                   -- modification date
  data number(38)
);

... y una secuencia

CREATE SEQUENCE s_test;

Un ID de configuración de disparador típico, usuario/fecha de creación/modificación

CREATE OR REPLACE TRIGGER t_test BEFORE INSERT OR UPDATE
  ON test
  FOR EACH ROW
BEGIN
  IF inserting THEN
    SELECT s_test.nextval INTO :new.id FROM dual;

    :new.uc := USER;
    :new.dc := SYSDATE;
    :new.um := NULL;
    :new.dm := NULL;
  END IF;
  IF updating THEN
    :new.um := USER;
    :new.dm := SYSDATE;
    :new.uc := :old.uc;
    :new.dc := :old.dc;
  END IF;
END t_test;

Insertar 1000, 10000, 100000 Registros

declare
  procedure run (limit number) is
    t timestamp;
  begin
    t := systimestamp;

    insert into test (data)
    select level from dual connect by level < limit;

    dbms_output.put_line(to_char(systimestamp - t));

    rollback;
  end;
begin
  run(1000);
  run(10000);
  run(100000);
end;

Resultados

-- ------------------------------------
-- +000000000 00:00:00.086603000
-- +000000000 00:00:00.844333000
-- +000000000 00:00:08.429186000
-- ------------------------------------

Otro activador "compatible" (orden de ejecución irrelevante)

CREATE OR REPLACE TRIGGER t_test_other BEFORE INSERT OR UPDATE
  ON test
  FOR EACH ROW
BEGIN
  :new.data := 42;
END t_test_other;

Resultados de otra ejecución del script de prueba

-- ------------------------------------
-- +000000000 00:00:00.088551000
-- +000000000 00:00:00.876028000
-- +000000000 00:00:08.731345000
-- ------------------------------------

Desactivar disparadores

alter trigger t_test disable;
alter trigger t_test_other disable;

Ejecute un script de prueba ligeramente diferente

declare
  procedure run (limit number) is
    t timestamp;
  begin
    t := systimestamp;

    insert into test (id, uc, dc, data)
    select s_test.nextval, user, sysdate, level from dual 
    connect by level < limit;

    dbms_output.put_line(to_char(systimestamp - t));

    rollback;
  end;
begin
  run(1000);
  run(10000);
  run(100000);
end;

Resultados

-- ------------------------------------
-- +000000000 00:00:00.012712000
-- +000000000 00:00:00.104903000
-- +000000000 00:00:01.043984000
-- ------------------------------------