Groovy Oracle Stored Proc - índice de columna inválido

El siguiente código puede ayudarlo a obtener la variable de SYS_REFCURSOR del bloque anónimo de Oracle.

Debemos centrarnos en algunos detalles clave:

1. Clase groovy.sql.Sql no tiene OutParameter correspondiente y lo hacemos manualmente como CURSOR_PARAMETER y páselo a sql.call método
2. Considere que el bloque comienza con {call DECLARE y termina con END } sin punto y coma después de FIN. De lo contrario, podemos obtener una SQLException poco reconocible en la cara.
3. Los signos de interrogación ? dentro de sqlString son lugares para enlaces de parámetros. Los enlaces se realizan en el orden natural tomando valores de parametersList .
   • En este ejemplo, tenemos el único enlace, por lo que ? se une con CURSOR_PARAMETER tratando el valor como OUT parámetro de tipo pasado;
4. Solo hay una entrada en el cierre después de sql.call y ResultSet rs proporcionar filas de cursor my_cur declarado en bloque anónimo.
5. Podemos simplificar sqlString usando una función que devuelve SYS_REFCURSOR en lugar de un procedimiento con OUT parámetro. Entonces podría verse así "{call BEGIN ? := MY_FUNC(); END}" o incluso "{? = call MY_FUNC()}"

import groovy.sql.OutParameter
import groovy.sql.Sql
import oracle.jdbc.OracleTypes

import java.sql.ResultSet

def driver = 'oracle.jdbc.driver.OracleDriver'
def sql = Sql.newInstance('jdbc:oracle:thin:@my-server:1521:XXX', 'usr', 'psw', driver)

// special OutParameter for cursor type
OutParameter CURSOR_PARAMETER = new OutParameter() {
    public int getType() {
        return OracleTypes.CURSOR;
    }
};

// look at some ceremonial wrappers around anonymous block
String sqlString = """{call
    DECLARE
      my_cur SYS_REFCURSOR;
    BEGIN
        STORED_PROCEDURE_NAME(my_cur);
        ? := my_cur;
    END
}
""";

// the order of elements matches the order of bindings
def parametersList = [CURSOR_PARAMETER];


// rs contains the result set of cursor my_cur
sql.call(sqlString, parametersList) { ResultSet rs ->
  while (rs.next()) {
      println rs.getString("my_column")
  }
};

PD Y gracias por la pregunta.