Un enfoque es utilizar Advanced Queuing de Oracle . Para ello, debe configurar una cola (y una tabla de colas) y escribir un procedimiento PL/SQL que espere el siguiente mensaje en la cola.
El lado de C++ luego llama al procedimiento PL/SQL, que regresa cuando ha ocurrido el próximo evento.
En el lado de Oracle, deberá usar DBMS_SCHEDULER o una instalación similar para crear el evento , es decir, para insertar un nuevo mensaje en la cola en el momento apropiado.
Sigue siendo un enfoque de sondeo. Sin embargo, no hay absolutamente ninguna actividad entre dos eventos.
Actualización:
Aquí hay un código de muestra.
Configuración inicial de la cola (el mensaje contiene un valor numérico y de texto):
grant AQ_ADMINISTRATOR_ROLE to appuser;
grant EXECUTE ON DBMS_AQ to appuser;
grant EXECUTE ON DBMS_AQ to appuser;
CREATE TYPE sample_payload_type AS OBJECT
(
cmd VARCHAR2(20),
id NUMBER
);
BEGIN
DBMS_AQADM.CREATE_QUEUE_TABLE (
queue_table => 'sample_queue_table',
queue_payload_type => 'sample_payload_type',
sort_list => 'ENQ_TIME',
compatible => '10.0'
);
END;
/
BEGIN
DBMS_AQADM.CREATE_QUEUE (
queue_name => 'sample_queue',
queue_table => 'sample_queue_table'
);
DBMS_AQADM.START_QUEUE (
queue_name => 'sample_queue'
);
END;
/
Encabezado del paquete:
create or replace package sample_queue_pkg
as
procedure get_next_msg(
i_max_wait number
,o_cmd out varchar2
,o_id out number
);
procedure put_msg(
i_cmd varchar2
,i_id number
);
end sample_queue_pkg;
/
Cuerpo del paquete:
create or replace package body sample_queue_pkg
as
procedure get_next_msg(
i_max_wait number
,o_cmd out varchar2
,o_id out number
)
is
dequeue_options dbms_aq.dequeue_options_t;
message_properties dbms_aq.message_properties_t;
message_handle RAW(16);
message sample_payload_type;
NO_MESSAGE_RECEIVED EXCEPTION;
PRAGMA EXCEPTION_INIT(NO_MESSAGE_RECEIVED, -25228);
begin
dequeue_options.wait := i_max_wait;
DBMS_AQ.DEQUEUE (
queue_name => 'appuser.sample_queue',
dequeue_options => dequeue_options,
message_properties => message_properties,
payload => message,
msgid => message_handle
);
o_cmd := message.cmd;
o_id := message.id;
exception
when NO_MESSAGE_RECEIVED then
o_cmd := null;
o_id := null;
end get_next_msg;
procedure put_msg(
i_cmd varchar2
,i_id number
)
is
enqueue_options dbms_aq.enqueue_options_t;
message_properties dbms_aq.message_properties_t;
message_handle RAW(16);
message sample_payload_type;
message_id NUMBER;
begin
message := sample_payload_type(i_cmd, i_id);
DBMS_AQ.ENQUEUE(
queue_name => 'appuser.sample_queue',
enqueue_options => enqueue_options,
message_properties => message_properties,
payload => message,
msgid => message_handle
);
end put_msg;
end sample_queue_pkg;
/
El servidor de la base de datos puede enviar un mensaje usando el siguiente código:
sample_queue_pkg.put_msg('run_task', 8234);
commit;
El servidor C++ puede esperar mensajes (y recibirlos) llamando al sample_queue_pkg.get_next_msg almacenado . El parámetro i_max_wait especifica el tiempo máximo de espera para el siguiente mensaje en segundos. Probablemente desee implementar un bucle que espere el siguiente mensaje y lo procese hasta que reciba una señal de que el servidor está a punto de cerrarse.
