La función de tabla con colección masiva arroja un tipo de datos no válido

Está intentando usar tipos de nivel de paquete en SQL simple, lo cual no está permitido. Los tipos declarados en el paquete no son visibles ni válidos fuera de PL/SQL (o incluso en declaraciones SQL simples dentro de PL/SQL). Una versión reducida de lo que estás haciendo:

create or replace package types as
    type my_rec_type is record (dummy dual.dummy%type);
    type my_table_type is table of my_rec_type index by binary_integer;
end types;
/

create or replace package p42 as
    function get_table return types.my_table_type;
end p42;
/

create or replace package body p42 as
    function get_table return types.my_table_type is
        my_table types.my_table_type;
    begin
        select * bulk collect into my_table from dual;
        return my_table;
    end get_table;
end p42;
/

select * from table(p42.get_table);

SQL Error: ORA-00902: invalid datatype

Incluso dentro del paquete, si tuviera un procedimiento que intentara usar la función de tabla, se produciría un error. Si agregó:

    procedure test_proc is
    begin
        for r in (select * from table(get_table)) loop
            null;
        end loop;
    end test_proc;

... la compilación del cuerpo del paquete fallaría con ORA-22905: cannot access rows from a non-nested table item .

Debe declarar los tipos a nivel de esquema, no en un paquete, por lo que debe usar SQL create type comando :

create type my_obj_type is object (dummy varchar2(1));
/

create type my_table_type is table of my_obj_type;
/

create or replace package p42 as
    function get_table return my_table_type;
end p42;
/

create or replace package body p42 as
    function get_table return my_table_type is
        my_table my_table_type;
    begin
        select my_obj_type(dummy) bulk collect into my_table from dual;
        return my_table;
    end get_table;
end p42;
/

select * from table(p42.get_table);

DUMMY
-----
X