sql >> Base de Datos >  >> RDS >> Sqlserver

Cómo obtener una lista de restricciones de clave principal de todas las bases de datos en la instancia de SQL Server - Tutorial de SQL Server / TSQL, parte 60

Escenario:

Está trabajando en la documentación de los objetos de la base de datos y se le pide que proporcione la lista de todas las restricciones de clave principal en todas las tablas de la base de datos en toda la instancia de SQL Server. ¿Cómo proporcionaría la lista de todas las restricciones de clave principal con nombre de base de datos, nombre de esquema, nombre de tabla, nombre de columna, nombre de restricción?

Solución:

Usaremos las vistas del sistema para obtener la información de restricción de clave principal. Como necesitamos ejecutar la consulta en toda la base de datos, usaremos Cursor con sql dinámico. Para cada base de datos, insertaremos los resultados en la tabla temporal y finalmente seleccionaremos el resultado al final de la tabla temporal para mostrarlo.

USE master
GO
--Declare Variables
DECLARE @DatabaseName AS VARCHAR(500)
--Create Temp Table to Save Results
IF OBJECT_ID('tempdb..#Results') IS NOT NULL
    DROP TABLE #Results
CREATE TABLE #Results (
    ServerName VARCHAR(128)
    ,DatabaseName VARCHAR(128)
    ,SchemaName VARCHAR(128)
    ,TableName VARCHAR(128)
    ,ColumnName VARCHAR(128)
    ,ConstraintName VARCHAR(128)
    )
DECLARE CUR CURSOR
FOR
SELECT '[' + NAME + ']' AS DBName
FROM sys.databases
WHERE NAME NOT IN (
        'master'
        ,'tempdb'
        ,'model'
        ,'msdb'
        )
OPEN Cur
FETCH NEXT
FROM Cur
INTO @DatabaseName
WHILE @@FETCH_STATUS = 0
BEGIN
    --Build dynamic sql for each database 
    DECLARE @SQL VARCHAR(MAX) = NULL
    SET @SQL = 'Insert into #Results
      Select
      @@ServerName,
   TC.Table_Catalog as DatabaseName,
   TC.Table_Schema AS TableSchema,
   TC.Table_Name AS TableName,
   CCU.Column_Name AS ColumnName,
   TC.Constraint_Name AS ConstraintName 
From' + @DatabaseName + '.information_Schema.Table_Constraints TC  
INNER JOIN
   ' + @DatabaseName + 
'.Information_Schema.constraint_column_usage CCU  
      on TC.Constraint_Name=CCU.Constraint_Name  
      and TC.Table_Name=CCU.Table_Name  
where
   Constraint_Type=''PRIMARY KEY'''
    EXEC (@SQL)
    PRINT @SQL
    FETCH NEXT
    FROM Cur
    INTO @DatabaseName
END
CLOSE Cur
DEALLOCATE Cur
--Select all records from temp table for Primary Key 
--Constraint Information
SELECT *
FROM #Results



Ejecuté la consulta anterior en mi instancia de SQL Server y obtuve la lista de todas las restricciones de clave principal con el nombre de la base de datos, el nombre del esquema, el nombre de la tabla, el nombre de la columna y el nombre de la restricción, como se muestra a continuación.
Cómo obtener una lista de todas las restricciones de clave principal de cada base de datos de la instancia de SQL Server - SQL Server / Tutorial T-SQL