¿Cómo obtener BLOB de un archivo en PL/SQL?

A continuación, doy un ejemplo de función para obtener el BLOB de un archivo en PL/SQL.

Función PL/SQL para obtener BLOB de un archivo

La siguiente función leerá un archivo y devolverá el tipo de datos BLOB del archivo. La función GET_BLOB toma dos parámetros:(1) nombre del objeto del directorio de Oracle (2) nombre del archivo.

CREATE OR REPLACE FUNCTION get_blob (i_dir IN VARCHAR2, i_file IN VARCHAR2)
   RETURN BLOB
AS
   l_bfile   BFILE;
   l_blob    BLOB;
BEGIN
   DBMS_LOB.createtemporary (l_blob, FALSE);
   l_bfile := BFILENAME (i_dir, i_file);
   DBMS_LOB.fileopen (l_bfile, DBMS_LOB.file_readonly);
   DBMS_LOB.loadfromfile (l_blob, l_bfile, DBMS_LOB.getlength (l_bfile));
   DBMS_LOB.fileclose (l_bfile);

   RETURN l_blob;
EXCEPTION
   WHEN OTHERS
   THEN
      IF DBMS_LOB.fileisopen (l_bfile) = 1
      THEN
         DBMS_LOB.fileclose (l_bfile);
      END IF;

      DBMS_LOB.freetemporary (l_blob);
      RAISE;
END get_blob;

Prueba

Suponga que tiene un archivo myimage.jpg en la carpeta C:\Pics, luego cree un objeto de directorio de Oracle, por ejemplo, MY_PICS para la carpeta C:\Pics y llame a la siguiente función pasando el nombre de directorio MY_PICS y el nombre de archivo myimage.jpg . Si no sabe cómo crear un objeto de directorio en Oracle, consulte este enlace:Crear objeto de directorio de Oracle.

DECLARE
   f_blob   BLOB;
BEGIN
   f_blob := get_blob ('MY_PICS', 'myimage.jpg');
END;

Ahora tienes el BLOB del archivo myimage.jpg en la variable f_blob.

Ver también:

• ¿Cómo insertar un archivo en la base de datos Oracle?