Problema en la creación de tablas dinámicas

La solución más sencilla sería eliminar la coma final al final:

dbms_output.put_line(rtrim(lsql,',') || ' )');

Parece que el procedimiento podría simplificarse a:

create or replace procedure p1(p_table_nm in varchar2)
is
    l_sql long := 'create table ' || p_table_nm || chr(10);
    l_colsep varchar2(2) := '( ';  -- changes to comma after first item
begin
    for rc1 in (
        select * from t1
        where  table_name = p_table_nm
    )
    loop
        l_sql := l_sql || l_colsep || rc1.column_name || ' ' || rc1.datatype ||
            case
                when rc1.column_width is not null then '(' || rc1.column_width || ')'
            end;

        if rc1.is_null = 'N' then  -- Changed from 'Y' - check requirement
            l_sql := l_sql || ' NOT NULL';
        end if;

        l_sql := l_sql || chr(10);
        l_colsep := ', ';
    end loop;

    dbms_output.put_line(rtrim(l_sql,chr(10)) || ' )');
end;

Esto da una salida como esta:

create table TEST
( FNAME VARCHAR2(10) 
, LNAME VARCHAR2(10) NOT NULL
, STARTDATE DATE NOT NULL )

¿Planea manejar valores predeterminados, identificadores generados, columnas virtuales o cualquier orden de columna específico?

También está seguro de que rc1.is_null = 'Y' significa que la columna es obligatoria? Parece lo contrario.