¿Cómo verificar si el archivo es una imagen usando PL/SQL?

En esta publicación de blog, comparto una función con la que puede verificar si un archivo es un archivo de imagen o no usa PL/SQL. El programa verificará el archivo leyendo su encabezado, no el nombre de la extensión del archivo. Actualmente, la función puede identificar tres tipos de imágenes que son JPG, PNG y GIF.

Función PL/SQL para verificar si el archivo es un archivo de imagen

La siguiente función PL/SQL leerá el encabezado del archivo y luego devolverá el tipo de imagen en el tipo de datos varchar2. La función get_image_type toma dos argumentos, y son los siguientes:

1. Objeto de directorio de Oracle (como i_dir) Aprenda a crear un objeto de Oracle Directory.
2. Nombre de archivo (como i_file) el archivo debe existir en el directorio.

CREATE OR REPLACE FUNCTION get_image_type (i_dir    IN VARCHAR2,
                                           i_file   IN VARCHAR2)
   RETURN VARCHAR2
AS
   l_bfile       BFILE;
   l_blob        BLOB;
   l_file_type   VARCHAR2 (50);
BEGIN
   DBMS_LOB.createtemporary (l_blob, FALSE);
   l_bfile := BFILENAME (i_dir, i_file);
   DBMS_LOB.fileopen (l_bfile, DBMS_LOB.file_readonly);
   DBMS_LOB.loadfromfile (l_blob, l_bfile, DBMS_LOB.getlength (l_bfile));
   DBMS_LOB.fileclose (l_bfile);

   IF RAWTOHEX (DBMS_LOB.SUBSTR (l_blob, 8, 1)) = '89504E470D0A1A0A'
   THEN
      l_file_type := 'PNG';
   ELSIF DBMS_LOB.SUBSTR (l_blob, 3, 1) = '474946'
   THEN
      l_file_type := 'GIF';
   ELSIF RAWTOHEX (DBMS_LOB.SUBSTR (l_blob, 3, 1)) = 'FFD8FF'
   THEN
      l_file_type := 'JPG';
   ELSE
      l_file_type := 'The file is not an image.';
   END IF;

   RETURN l_file_type;
EXCEPTION
   WHEN OTHERS
   THEN
      IF DBMS_LOB.fileisopen (l_bfile) = 1
      THEN
         DBMS_LOB.fileclose (l_bfile);
      END IF;

      DBMS_LOB.freetemporary (l_blob);
      RETURN 'The file does not exists.';
END get_image_type;

Prueba

En el siguiente programa PL/SQL, cambie el objeto de directorio de Oracle MY_FILES con su objeto de directorio y cambie el nombre del archivo con el archivo disponible en la ubicación del directorio MY_FILES.

SET SERVEROUTPUT ON;

DECLARE
   i_image_type   VARCHAR2 (50);
BEGIN
   i_image_type := get_image_type ('MY_FILES', 'oracle-logo-gif-to-use.gif');

   IF i_image_type IN ('JPG', 'GIF', 'PNG')
   THEN
      DBMS_OUTPUT.put_line ('The file is a valid ' || i_image_type || ' image.');
   ELSE
      DBMS_OUTPUT.put_line (i_image_type);
   END IF;
END;
/

Salida

The file is a valid GIF image.
PL/SQL procedure successfully completed.

Ver también:

• ¿Cómo insertar un archivo en una tabla de Oracle usando PL/SQL?