Al menos perdiste una definición de tabla en el segundo caso. Esta declaración:
create or replace TYPE tbl_list2 IS OBJECT (l_owner VARCHAR2(64),l_name VARCHAR2(64));
declara solo el tipo de objeto (o registro), no una tabla.
Entonces necesitas hacerlo en 2 pasos:
create or replace TYPE tbl_list_rec IS OBJECT (l_owner VARCHAR2(64),l_name VARCHAR2(64));
/
create or replace TYPE tbl_list2 as table of tbl_list_rec;
/
Después de eso, necesita algunas correcciones de sintaxis en el script:
declare
l_object tbl_list2;
i number;
begin
-- for list initialization it must be filled with constructed objects
l_object := tbl_list2( tbl_list_rec('','') );
for i in 1..100000 loop
-- 1. select values to variable
-- 2. Fix constructor for list
select
l_object MULTISET UNION DISTINCT tbl_list2(tbl_list_rec('myOwner','MyTable'))
into
l_object
from
dual;
end loop;
for i in l_object.first .. l_object.last loop
-- output separate fields, there are now default conversion from
-- user-defined objects to varchar2.
dbms_output.put_line(l_object(i).l_owner || ',' || l_object(i).l_name);
end loop;
end;
/
ACTUALIZAR
La solución anterior es relativamente lenta debido a la gran cantidad de cambios de contexto. Pero la comparación de instancias de tipos de objetos complejos no se puede hacer directamente en PL/SQL sin trabajo adicional.
Para permitir que Oracle sepa si las instancias de objetos son iguales o diferentes, necesitamos definir método de mapeo u ordenamiento para tipo de objeto
. Ambos tipos de métodos no están permitidos, por lo que es necesario elegir el adecuado. Los métodos MAP funcionan más rápido y no hay necesidad de ordenar en nuestro caso, así que adelante:
create or replace TYPE tbl_list_rec2 AS OBJECT (
l_owner VARCHAR2(64),
l_name VARCHAR2(64),
map member function get_key return varchar2
);
/
Implementación:
create or replace TYPE BODY tbl_list_rec2 AS
map member function get_key return varchar2
is
begin
return l_owner||chr(1)||l_name;
end;
end;
/
Después de eso, es posible probar la igualdad de los objetos en el código PL/SQL como el simple varchar2
en el primer ejemplo de la pregunta:
declare
l_object tbl_list2a;
i number;
begin
l_object := tbl_list2a( tbl_list_rec2('','') );
for i in 1..100000 loop
l_object := l_object MULTISET UNION DISTINCT tbl_list2a(tbl_list_rec2('myOwner','MyTable'));
end loop;
for i in l_object.first.. l_object.last loop
dbms_output.put_line(l_object(i).l_owner || ',' || l_object(i).l_name);
end loop;
end;
/