No haga bucles dentro de bucles en PL/SQL para esto:use SQL para obtener los datos listos para usar.
Primero creamos su tabla con algunos datos de prueba (supongo que tipos de datos, los reemplaza con los suyos):
create table product_master (
product_no varchar2(10)
, product_holder varchar2(10)
, product_catalogue varchar2(10)
)
/
insert into product_master values ('1', 'SMITH', 'TEMP')
/
insert into product_master values ('2', 'SMITH', 'TEMP')
/
insert into product_master values ('3', 'HARRY', 'ARCH')
/
insert into product_master values ('4', 'TOM' , 'DEPL')
/
commit
/
Lo que queremos enviar a mail_send procedimiento para cada product_holder es una colección (matriz) que contiene product_no y product_catalogue . Así que primero un tipo que contenga esos dos elementos:
create type t_prod_cat_no as object (
product_no varchar2(10)
, product_catalogue varchar2(10)
)
/
Y luego un tipo de tabla anidada (tipo de colección) de ese tipo:
create type t_prod_cat_no_table as
table of t_prod_cat_no
/
El procedimiento mail_send entonces debería aceptar el product_holder y el tipo de colección:
create or replace procedure mail_send (
p_parameter in varchar2
, p_product_holder in varchar2
, p_product_cats_nos in t_prod_cat_no_table
)
is
begin
dbms_output.put_line('-- BEGIN '||p_parameter||' --');
dbms_output.put_line('Dear '||p_product_holder);
dbms_output.put_line('Your products are:');
for i in 1..p_product_cats_nos.count loop
dbms_output.put_line(
'Catalogue: '||p_product_cats_nos(i).product_catalogue||
' - No: '||p_product_cats_nos(i).product_no
);
end loop;
end mail_send;
/
(Solo uso dbms_output para simular la creación de un correo).
Entonces puedes en SQL hacer un group by product_holder y deja que SQL genere la colección que contiene los datos:
begin
for holder in (
select pm.product_holder
, cast(
collect(
t_prod_cat_no(pm.product_no,pm.product_catalogue)
order by pm.product_catalogue
, pm.product_no
) as t_prod_cat_no_table
) product_cats_nos
from product_master pm
group by pm.product_holder
order by pm.product_holder
) loop
mail_send(
'PRODMASTER'
, holder.product_holder
, holder.product_cats_nos
);
end loop;
end;
/
La salida del bloque anterior será:
-- BEGIN PRODMASTER --
Dear HARRY
Your products are:
Catalogue: ARCH - No: 3
-- BEGIN PRODMASTER --
Dear SMITH
Your products are:
Catalogue: TEMP - No: 1
Catalogue: TEMP - No: 2
-- BEGIN PRODMASTER --
Dear TOM
Your products are:
Catalogue: DEPL - No: 4
Haciéndolo en SQL con un GROUP BY le brinda todo en una sola llamada de PL/SQL a SQL, que es mucho más eficiente que la primera llamada para obtener el conjunto distinto de product_holder , repita eso y luego una llamada por product_holder para obtener los productos para cada titular.
ACTUALIZAR:
Añadido order by al collect función en el código anterior para mostrar que tiene control sobre el orden en que se completan los datos en la colección.
