¿Cómo dividir una cadena en PL/SQL?

En este artículo, doy un ejemplo de una función que uso principalmente para dividir una cadena en PL/SQL. Especialmente, cuando estoy escribiendo un programa para importar un archivo delimitado. Aquí está esa función y un ejemplo de cómo usarla.

Función PL/SQL para dividir una cadena

Esta función toma cuatro parámetros, y los detalles de estos parámetros son los siguientes:

1. Cadena_fuente :Cadena a dividir
2. Posición_del_campo :Posición del delimitador
3. Sin terminar :False de forma predeterminada, pero si pasa True, agregará el delimitador especificado al final de la cadena.
4. Delimitador :El valor predeterminado es Coma ',', puede pasar cualquier otro delimitador.

CREATE OR REPLACE FUNCTION GetString (
Source_string IN VARCHAR2,
Field_position IN NUMBER,
UnTerminated IN BOOLEAN DEFAULT FALSE,
Delimiter IN VARCHAR2 DEFAULT ',')
RETURN VARCHAR2
IS
iPtrEnd PLS_INTEGER := 0;
iPtrStart PLS_INTEGER := 0;
vcSourceStrCopy VARCHAR2 (4000) := Source_string;
BEGIN
IF UnTerminated
THEN
vcSourceStrCopy := vcSourceStrCopy || Delimiter;
END IF;

IF Field_Position > 1
THEN
iPtrStart :=
INSTR (vcSourceStrCopy,
Delimiter,
1,
Field_Position - 1)
+ LENGTH (Delimiter);
ELSE
iPtrStart := 1;
END IF;

iPtrEnd :=
INSTR (vcSourceStrCopy,
Delimiter,
1,
Field_Position);
RETURN SUBSTR (vcSourceStrCopy, iPtrStart, (iPtrEnd - iPtrStart));
END GetString;

Ejemplo:usar esta función en el programa PL/SQL

SET SERVEROUTPUT ON;

DECLARE
   v_string      VARCHAR2 (1000) := 'Java|.Net|C|Oracle|PHP';

   TYPE t_string IS TABLE OF VARCHAR2 (1000)
                       INDEX BY BINARY_INTEGER;

   t_str_array   t_string;
BEGIN
   FOR i IN 1 .. 5
   LOOP
      t_str_array (i) :=
         getstring (v_string,
                    i,
                    TRUE,
                    '|');
   END LOOP;

   FOR j IN t_str_array.FIRST .. t_str_array.LAST
   LOOP
      DBMS_OUTPUT.put_Line (t_str_array (j));
   END LOOP;
END;
/

Salida:

Java
.Net
C
Oracle
PHP
PL/SQL procedure successfully completed.

Ver también:

• Exportar datos a JSON utilizando PL/SQL en Oracle 11g
• Programa PL/SQL para imprimir detalles de empleados